Gazira Babeli

iDol Interacting With Aliens Buy Gaz' 4 One Linden... GAZ OF THE DESERT Anna Magnani Who's Afraid of Madeleine... Ultimate Submission Grey Goo Come To Heaven Don't Say Gaz Quake Second Soup Singing Pizza Second Jesus

all WORKS

Olym Pong You Love Pop... Save Your Skin Ursonate in Second Life Unbroken Eggs Come Together Nudes Descending a Staircase Collateral Damage Avatar On Canvas Second Soup

Gazira Babeli
Code Performer

ACTS /
WORKS /

Second Soup. You love Pop Art - Pop Art hates you

Scripted cans, May 2006

Second Soup installation, Locusolus Archive [SLurl]

Second Soup performances, stills from video

Second Soup LSL code

// =================================================
// Second Soup v1.2
// You love Pop Art - Pop Art hates you!
// ===========
// (cc) 2006 Gazira Babeli - gazirababeli.com
// =================================================
// This work is licensed under a Creative Commons
// Attribution-NonCommercial-NoDerivs 2.5 License
// http://creativecommons.org/licenses/by-nc-nd/2.5/
// =================================================
//
// HOW TO: Drag/Copy/Add this script on a prim
//
string popartlover;
vector pos;
vector relpos;
float range = 7;
float poprange = 4;
float shake = .4;

default
{
    state_entry()
    {
     llSetObjectName("Second Soup");
     llSetObjectDesc("By Gazira Babeli");
     llSetPrimitiveParams([PRIM_PHYSICS, FALSE]);
     llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_CYLINDER, 0, <0,1,0>,
                              0, ZERO_VECTOR, <1,1,0>, ZERO_VECTOR]);
     llSetPrimitiveParams([PRIM_SIZE, <1.1,1.1,1.6>]);
     llSetTexture("1f7b4ec8-2917-c356-5192-6bbcfffa4f5a", 1);
     llSetTexture("f6d64696-2f0f-66cc-f06e-e3ec0d9a4fa7", 0);
     llSetTexture("f6d64696-2f0f-66cc-f06e-e3ec0d9a4fa7", 2);
     state wait;
    }
}

state wait
{
    state_entry()
    {
     llSetPrimitiveParams([PRIM_PHYSICS, TRUE]);
     llSensorRepeat("", NULL_KEY, AGENT, range, TWO_PI, 1);
    }

sensor(integer total_number)
    {
     llSetPrimitiveParams([PRIM_PHYSICS, FALSE]);
     llSetPos(llGetPos() + <0,0,shake>);
     llSetRot(llDetectedRot(0));
     relpos = llGetPos();
     popartlover = llDetectedName(0);
     llSay(0, popartlover + "... You love Pop Art - Pop Art hates you!");
     state pop;
    }
}

state pop
{
    state_entry()
    {
     llSensorRepeat(popartlover, NULL_KEY, AGENT, poprange, TWO_PI, .1);
    }

sensor(integer total_number)
    {
     pos = llDetectedPos(0);
     llSetPos(pos + <0,0,shake>);
     llSetPos(pos - <0,0,shake>);
     if (llVecDist(pos, relpos) > range) state back;
    }

no_sensor()
    {
     state back;
    }
}

state back
{
    state_entry()
    {
     llSetPos(relpos);
     llSleep(.5);
     state wait;
    }
}